All of this applies if you have either a single monitor or more than one monitor.
This guide will go over how to setup a fullsreen script that both makes your FA run in windowed full screen (AKA: fake-fullscreen) and optimizes FA in order to gain a bit of performance.
There are multiple versions of the script depending on your monitor setup, and whether you just want the windowed fullscreen, the optimization, or both.
I’ll just give you the baseline and then step by step it so you can meet your needs.
(Single monitor (at any resolution) example first)
- run a test game of FA and go into graphic settings and set the resolution to « windowed » (you may now exit FA)
- download and install AutoHotkey (when it is done installing don't run, there's nothing to run. Just close the installer)
- hit Win+"R"
- type "shell:startup"
- in the folder that opens right click go to "New" -> "AutohotkeyScript" this should create a new ahk file. (You can name it fullscreenScript or something similar)
Open this file with notepad or notepad++ ( or equivalent basic text editor that can edit code)
(best version of this script : https://forum.faforever.com/topic/123/guide-fake-fullscreen-and-optimisation/27 )
paste this (this is the script you will have to adapt to suit your needs)
#NoEnv
SendMode Input
SetWorkingDir %A_ScriptDir%
#Persistent
procName := "ForgedAlliance.exe"
SetTimer, CheckProc, 2000
Return
CheckProc:
If (!ProcessExist(procName))
Return
WinGet Style, Style, % "ahk_exe " procName
If (Style & 0xC40000)
{
WinSet, Style, -0xC40000, % "ahk_exe " procName
WinMinimize , % "ahk_exe " procName
WinMaximize, % "ahk_exe " procName
Run, %comspec% /c process -a forgedalliance.exe 1110
Run, %comspec% /c process -p forgedalliance.exe high
}
Return
ProcessExist(exeName)
{
Process, Exist, %exeName%
return !!ERRORLEVEL
}
return
The Run, %comspec% bit is the part you can remove (two lines) if you’re not interested in the optimization.
However, if you are interested, edit the 1110 on that line to fit your processor thread count. Mine has twelve so my number has twelve digits E.G. : 111111111110
- when you’re satisfied with your edits hit ctrl-S, then alt-F4 to exit your text editor.
- (if not interested in optimisation skip this) download this : https://github.com/tatsujb/Process.exe/raw/master/Process.exe and place this file (Process.exe) in c:\windows\system32
- You’re done! you can either restart the computer or double click the file
- (Optional although strongly recommended, especially if you have two monitors) add « UI Party » in the mod vault and enable it by hosting a test game with it (you’ll have to configure UI Party)
(Example with two 1080p monitors that are ordered left to right you’ll need to adapt the pixel sizes if your monitors are a different resolution than 1080p, note that FA is now a window so it can’t stretch it’s bottom border two different amounts, if you have different resolution monitors one of the two monitors will not be completely filled.)
#NoEnv
SendMode Input
SetWorkingDir %A_ScriptDir%
#Persistent
procName := "ForgedAlliance.exe"
SetTimer, CheckProc, 2000
Return
CheckProc:
If (!ProcessExist(procName))
Return
WinGet Style, Style, % "ahk_exe " procName
If (Style & 0xC40000)
{
WinSet, Style, -0xC40000, % "ahk_exe " procName ; remove the titlebar and border(s)
WinMove, % "ahk_exe " procName , , 0, 0, 3840, 1080 ; move the window to 0,0 and resize it to fit across 2 monitors.
WinMaximize, % "ahk_exe " procName
WinRestore, % "ahk_exe " procName
Run, %comspec% /c process -a forgedalliance.exe 1110
Run, %comspec% /c process -p forgedalliance.exe high
}
Return
ProcessExist(exeName)
{
Process, Exist, %exeName%
return !!ERRORLEVEL
}
return
Go here for full sets of examples : https://forums.faforever.com/viewtopic.php?f=2&t=9778
Here is an exe version : https://forums.faforever.com/viewtopic.php?f=2&t=9778&start=40#p154100
How to correctly handle two different sized screens : https://forums.faforever.com/viewtopic.php?f=2&t=9778&start=90#p185820
The breakdown, for those who like understanding the nuts and bolts of what they use :
I use autohotkey (AKA : AHK) as a scripting language here because AHK has absolutely no performance hit on your system especially in the case of this script and if it’s the only one.
The first couple lines set our variables namely the process name that we’re looking for (E.G. « ForgedAlliance.exe » . Yes, this does imply that simply by replacing this you can get the same full screen effect on any other game or app).
Then we tell it to disable the window border,
Then we tell it to minimize,
Then, in the first example I listed, to maximize (which when you don’t have a window border means the entire screen) ( in the second example I listed I set it to the combined dual monitor resolution)
That’s fake fullscreen.
The optimisation bit is something that works for FA for the following reasons :
- FA always starts on the first core/thread
- FA is mainly a single thread, single core app. It has a second thread for the user interface (which accounts for about 5% of FA’s cpu usage so it doesn’t really matter, it’s thread/core is generally very idle). The main thread/core however generally averages at 100% usage.
- windows boots and runs it’s main services on the first core/thread.
This combination of factors means that moving FA main thread to another thread, any other thread, yields overhead that you aren’t otherwise getting.
Right, so you could just open your task manager after launching a game, find FA in the details tab (not the processes tab) right click it and set core affinity and remove the checkmark on the first core and apply.
Well this was a popular thing to do by hand but I found it tedious so I automated it.
This was a bit tricky as normally no non-admin process could modify other threads in this way. But I found an old archaic Microsoft system32 tool, crudely named « Process » which you can pipe a process name to plus what you want it to do to it without requiring any privileges of any sort. Neat. #justwindowsthings
So I use process. Why do I place it in system32? Because that’s the equivalent on windows to adding it to the path suddenly when AHK makes a console call (Run) of that name (process) it is found. Perfect.
So what is this 1110, 111111111110 deal? Process takes ones and zeroes as arguments for its thread affinity parameter. One means « use thread » zero means « don’t use this thread ». For whatever reason they are listed backwards, this is why the zero is last (we’re trying not to use the first thread). Ok so how many ones do I put? As many as you have threads on your CPU minus the last one where you’ll put a zero instead, an easy way to check is to open task manager and right click on the cpu graph and select « show logical cores » and count the graphs.
In the second line that calls process I do something else, what is that? Yes, I’m also setting FA’s process priority to high.
For 99% of apps this does ABSOLUTELY NOTHING. But for some reason FA is apparently not already getting a fair shake from window (8 and up (that means windows 10))’s task prioritizer. Weird, I know. We take those.
There now you understand the whole fullscreen/optimisation script.
AHK gets flagged as a hack/cheat/bot by Black Desert Online’s anti cheat software!
Uhm, if you’re letting rootkits onto your computer, you’re fucking yourself already, I can’t help there. Don’t play games that impose rootkit software as an anticheat, this needs to be intergrated into gamer culture. That these rootkits are « official » rootkits does not make it any better and it calling AHK « a cheat » is really the pot calling the kettle black considering rootkits are malware.
what’s the Linux step by step
Well the whole core optimisation thing is moot since Linux abstracts away threads and doesn’t « order » them or « start a process on a specific thread ». The overhead and prioritazation are also moot because you’re not emulating a full windows, just the parts you need, and lastly the windowed is moot because the emulation plus whatever DE you have basically kinda result in the same result. There’s only the multiple monitor thing I would be curious to know how to do.
Hope this helps thousands of people!